;---------------------------------------------------
	; Copyright Karl-Uwe Frank
	;
	; I place this source code into Public Domain
	;
	
	
	;---------------------------------------------------
	; http://rosettacode.org/wiki/Entropy#PureBasic
	;
	;Global NewMap uchar.i() : 
	Global.d e
	 
	Procedure.d nlog2(x.d) : ProcedureReturn Log(x)/Log(2) : EndProcedure
	 
	Procedure countchar(s$, Map uchar())
	  If Len(s$)
	    uchar(Left(s$,1))=CountString(s$,Left(s$,1))
	    s$=RemoveString(s$,Left(s$,1))
	    ProcedureReturn countchar(s$, uchar())
	  EndIf
	EndProcedure
	;---------------------------------------------------
	
	
	Global.s key, key_hash, hash_hex, info_pwd, info_hash

	Procedure CheckKeyword()
		info_pwd = ""
		
		;---------------------------------------------------
		; Check the Entropy of the Keyword String
		;
		NewMap uchar.i()
		e = 0
		countchar(key, uchar())
		 
		ForEach uchar()  
		  e-uchar()/Len(key)*nlog2(uchar()/Len(key))  
		Next
			
		;---------------------------------------------------
		; Convert the Keyword String into Hex Values
		;
		For i = 1 To Len(key)-1
			info_pwd + LCase(RSet(Hex(Asc(Mid(key,i,1))), 2, "0")) +":"
		Next
		
		info_pwd + LCase(RSet(Hex(Asc(Mid(key,i,1))), 2, "0")) +#CRLF$+#CRLF$
		info_pwd + "Entropy = "+StrD(e,15)
	EndProcedure
	
	Procedure CheckHash()
		info_hash = ""
		key_hash  = ""
		hash_hex	= ""
		
		UseSHA2Fingerprint()
		key_hash = StringFingerprint(key, #PB_Cipher_SHA2, 512)
		
		;---------------------------------------------------
		; Convert the Hash Hex Text String back to Hex Values
		;
		For i = 0 To Len(key_hash)-1
			hash_hex + Chr(Val("$"+Mid(key_hash, (i*2)+1, 2)))
		Next
		
		;---------------------------------------------------
		; Compare the Entropy of this Hex String
		;
		NewMap uchar.i()
		e = 0
		countchar(hash_hex, uchar())
		
		ForEach uchar()  
		  e-uchar()/Len(hash_hex)*nlog2(uchar()/Len(hash_hex))  
		Next
			
		For i = 0 To (Len(key_hash)/2)-2
			info_hash + Mid(key_hash, (i*2)+1, 2) +":"
		Next
		
		info_hash + Mid(key_hash, (i*2)+1, 2) +#CRLF$+#CRLF$
		info_hash + "Entropy = "+StrD(e,15)
	EndProcedure
	
	;---------------------------------------------------
	; Show info in a Window
	;	
	Global Quit.b = #False
	
	Enumeration ; Gadgets
	  #PWD_INPUT
	  #INFO_PWD
	  #INFO_HASH
	  #BUTTON_CHECK
	  #BUTTON_CLOSE   
	EndEnumeration 

	If OpenWindow(#PB_Any, 100, 200, 600, 400, "Keyword Entropy Check", #PB_Window_SystemMenu | #PB_Window_ScreenCentered) = 0
		MessageRequester("Error", "Can't open Window", 0)
	  End 1
	EndIf		

  TextGadget(		#PB_Any,  			50,  12,  60,  20, "Keyword")
  StringGadget(	#PWD_INPUT, 	 120,  10, 430,  20, "1234")
  
  FrameGadget(	#PB_Any,  			40,  40, 510, 140, "Keyword as Hex String")
  TextGadget(		#INFO_PWD,  		50,  60, 470, 140, info_pwd)

  FrameGadget(	#PB_Any,  			40, 190, 510, 140, "Keyword hashed with SHA-2 (512bit) as Hex Value")
  TextGadget(		#INFO_HASH,  		50, 210, 470, 140, info_hash)
 
  ButtonGadget(	#BUTTON_CHECK, 360, 360, 120,  25, "Check Entropy")
  ButtonGadget(	#BUTTON_CLOSE, 490, 360,  60,  25, "Quit")
  
  SetActiveGadget(#PWD_INPUT)
  
  Repeat
  	Event = WaitWindowEvent()
  	
  	Select Event
  			
  		Case #PB_Event_Gadget
  			Select EventGadget()
  				Case #BUTTON_CHECK
  					key = GetGadgetText(#PWD_INPUT)
  					
  					CheckKeyword()
  					CheckHash()
  					
  					SetGadgetText(#INFO_PWD,  info_pwd)
  					SetGadgetText(#INFO_HASH, info_hash)
  					
  				Case #BUTTON_CLOSE : Quit = #True
  			EndSelect
  			
  	EndSelect
  	
  Until (Event = #PB_Event_CloseWindow) Or (Quit = #True)
  
  End 0